software: Added more and more

[pdp8.git] / sw / os8 / v3d / sources / system / dectapes / dectape1 / C2BOOT.PA

/SECONDARY BOOTSTRAP V5A
/
/
/
/
/
/
/
/
/
/COPYRIGHT  (C)  1973,1974 BY DIGITAL EQUIPMENT CORPORATION
/
/
/
/
/
/
/
/
/
/
/THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
/AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
/CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
/
/THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
/UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
/(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
/SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
/
/DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
/OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
/DIGITAL.
/
/
/
/
/
/
/
/
/
/
\f
/	DEC-8E-OC2BA-A-LA
/	COPYRIGHT 1972
/	DIGITAL EQUIPMENT CORPORATION
/	MAYNARD, MASS.  01754

/	S.R.

	VERSON=	5	/5= VERSION 5, ETC
	SUBVER=	01	/01=A, ETC

	BSW=7002
	KSDR=6701
	KSDF=6701
	KSBF=6703
	KLSA=6704
	KGOA=6706
	KRSB=6707
	NOPUNCH
	*3602
	ENPUNCH

BIN,	STA
	DCA GRKNT
ITSFLD,	TAD CDF0
	DCA FLD
ITSORG,	DCA ORG		/ASSUMES ORIGIN ALWAYS APPEARS
			/AFTER FIELD SETTING
BINLDR,	STA
	DCA ORGSW
	JMS GETBYT
FOOL,	BSW
	CLL RTR
	SZL
	JMP SPEC	/BIT 4=1
	SPA		/BIT 4=0 (TWO WORD COMMAND)
	ISZ ORGSW	/IS ORIGIN
N7000,	NOP
	RAL
	CLL RAL
	DCA TEM
	JMS GETBYT
	TAD TEM		/COMBINE
	ISZ ORGSW
	JMP ITSORG	/ORIGIN
FLD,	HLT
	DCA I ORG
	ISZ ORG
CDF0,	CDF 0
	JMP BINLDR
SPEC,	SMA
	JMP	MON
	RTL
	AND N7000
	BSW
	JMP ITSFLD
\fGETBYT,	0
	ISZ	GRKNT
	JMP	RDBYTE
	TAD	X260
	KLSA
	KGOA
	KSBF
	JMP	.-1
	KRSB
	AND	X7774
	SZA CLA
	HLT
	ISZ	FIRST
	JMP	NOTFST
	JMS RESET
	TAD	X270
	STL
	JMP I	X4002
NOTFST,	TAD	X7600
	DCA	GRKNT
	TAD	X200
	KLSA
	KGOA
	KSDF
	JMP	.-1
RDBYTE,	KGOA
	KSDF
	JMP	.-1
	JMP I	GETBYT

	ZBLOCK 3701-.	/LOCATION 3701 IS SKIPPED BY PRIMARY LOADER


	NOPUNCH
	0
	ENPUNCH
\fMON,	CDF CIF 10
	JMP I	.+1
	5200

ORG,	0
TEM,	0
ORGSW,	0

X200,	200
X260,	260
X270,	270
X7737,	7737
XKNT,	4035
XPTR,	4036
X4002,	4002
GRKNT,	0
X7774,	7774
FIRST,	-1
X7600,	7600
RESET,	0		/SET UP PRIMARY BOOTSTRAP FOR REUSE
	TAD	X7737
	DCA I	XKNT
	DCA I	XPTR
	TAD X3211	/A "DCA ." FOR LOCATION 4011
	DCA I X4011
	JMP I RESET
X3211,	3211
X4011,	4011
	ZBLOCK 4000-.
	BIN
	JMP I .-1	/MUST END IN OCTAL 00
	$
\fGETBYT,	0	/DF IS RAANDOM ON ENTRY
	CDF 10
	ISZ GRKNT
	JMP TB
	TAD (-200
	DCA GRKNT
	TAD (BINBUF
	DCA GRPTR
	CALL (HANDLER
	READ+F1
	BINBUF
	HLT
	CALL XWAIT
TB,	TAD I GRPTR
	INCR GRPTR
	EXIT GETBYT

GRKNT,	0
GRPTR,	0

/	00	DATA
/	01	ORIGIN
/	11	FIELD
/	10	LEADER/TRAILER
	PAGE
	$