sw/os8/v3d/sources/devext/dectapes/dectape1/ccldat.ma

   1 /
   2 /
   3 /
   4 /COPYRIGHT  (C)  1979 BY DIGITAL EQUIPMENT CORPORATION
   5 /
   6 /
   7 /
   8 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
   9 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  10 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  11 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  12 /
  13 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  14 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  15 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  16 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  17 /
  18 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  19 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  20 /DIGITAL.
  21 /
  22 /
  23 /
  24
  25 \f
  26 /VERSION=V3A (D.H.)
  27 \f/3     CCL DATE COMMAND
  28
  29         .ENTRY DATE
  30         .EXTERNAL PRINT,OTOD,PRWD,PRMESG
  31         .EXTERNAL CRLF,LOOK,CHAIN
  32         .EXTERNAL YDATE
  33
  34         DATWD=7666
  35         BATCCL=7777
  36
  37         .RSECT CCLDAT
  38         FIELD 1
  39
  40 DATE,   0
  41         TAD I (DATWD
  42         SNA
  43         JMP NODATE
  44         DCA DATEM
  45         TAD DATEM
  46         CLL RTL
  47         RTL
  48         RAL
  49         AND (17
  50         DCA TM1
  51         TAD TM1
  52         TAD (MONLST-1
  53         DCA TM2
  54         TAD I TM2
  55         DCA 4$
  56         TAD DATEM
  57         AND (7
  58         DCA T$
  59         CDF 0
  60         TAD I (BATCCL
  61         CDF 10
  62         CLL RTR
  63         RTR
  64         AND (30
  65         TAD T$
  66         DCA TM2
  67         TAD TM2
  68         TAD (70.
  69         JMS I (OTOD
  70         DCA YEAR
  71         TAD DATEM
  72         CLL RTR
  73         RAR
  74         AND (37
  75         DCA DATEM
  76         TAD DATEM
  77         JMS I (OTOD
  78         DCA DAY
  79         STL CLA RTL     /2
  80         TAD TM2
  81         CLL RTR
  82         SNL SMA
  83         JMP 1$
  84         ISZ I (JAN
  85         ISZ I (FEB
  86 1$:     AND (37
  87         TAD TM2
  88         TAD (3
  89         TAD DATEM
  90         DCA DATEM
  91         TAD TM1
  92         TAD (JAN-1
  93         DCA TM1
  94         TAD I TM1
  95         TAD DATEM
  96 2$:     CLL
  97         TAD (-7
  98         SZL
  99         JMP 2$
 100         TAD (7
 101         TAD (WEEKLST
 102         DCA TM2
 103         TAD I TM2
 104         DCA 3$
 105         STA             /DON'T CRLF AND PRINT IN LOWER CASE
 106         JMS I (PRINT
 107 3$:     0
 108         STA
 109         JMS I (PRINT
 110         DAYDAY
 111         CLA IAC
 112         JMS I (PRINT
 113 4$:     0
 114         STL CLA RAR
 115         JMS I (PRWD     /SPACE
 116         TAD DAY
 117         JMS I (PRWD
 118         CLA IAC
 119         JMS I (PRINT
 120         COM19
 121         TAD YEAR
 122         JMS I (PRWD
 123         JMS I (CRLF
 124         JMS I (LOOK     /LOOKUP SYS:DATE.SV
 125         YDATE
 126         JMP I DATE      /DO NOTHING IF IT'S NOT THERE
 127         JMP I (CHAIN    /CHAIN TO IT, IF IT'S THERE
 128 T$:     0
 129 \fNODATE,        JMS I (PRMESG
 130         NONE
 131 TM1,    0
 132 TM2,    0
 133 DATEM,  0
 134 DAY,    0
 135 YEAR,   0
 136
 137 NONE,   TEXT    /NONE/
 138         PAGE
 139 \fMONLST,        MON1
 140         MON2
 141         MON3
 142         MON4
 143         MON5
 144         MON6
 145         MON7
 146         MON8
 147         MON9
 148         MON10
 149         MON11
 150         MON12
 151 \fMON1,  TEXT    /JANUARY/
 152 MON2,   TEXT    /FEBRUARY/
 153 MON3,   TEXT    /MARCH/
 154 MON4,   TEXT    /APRIL/
 155 MON5,   TEXT    /MAY/
 156 MON6,   TEXT    /JUNE/
 157 MON7,   TEXT    /JULY/
 158 MON8,   TEXT    /AUGUST/
 159 MON9,   TEXT    /SEPTEMBER/
 160 MON10,  TEXT    /OCTOBER/
 161 MON11,  TEXT    /NOVEMBER/
 162 MON12,  TEXT    /DECEMBER/
 163 \fCOM19, TEXT    /, 19/
 164
 165 WEEKLST,DAY1
 166         DAY2
 167         DAY3
 168         DAY4
 169         DAY5
 170         DAY6
 171         DAY7
 172
 173         .ENABLE ASCII
 174 DAY1,   TEXT    /Satur/
 175 DAY2,   TEXT    /Sun/
 176 DAY3,   TEXT    /Mon/
 177 DAY4,   TEXT    /Tues/
 178 DAY5,   TEXT    /Wednes/
 179 DAY6,   TEXT    /Thurs/
 180 DAY7,   TEXT    /Fri/
 181 DAYDAY, TEXT    /day /
 182         .ENABLE SIXBIT
 183
 184 JAN,    0
 185 FEB,    3
 186         4;0;2;5;0;3;6;1;4;6
 187