sw/os8/v3d/sources/devext/dectapes/dectape1/cclsem.ma

   1 /
   2 /
   3 /
   4 /COPYRIGHT  (C)  1979 BY DIGITAL EQUIPMENT CORPORATION
   5 /
   6 /
   7 /
   8 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
   9 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  10 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  11 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  12 /
  13 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  14 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  15 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  16 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  17 /
  18 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  19 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  20 /DIGITAL.
  21 /
  22 /
  23 /
  24
  25 \f
  26 /VERSION=V3A (D.H.)
  27 \f/1     CCL SEMICOLON CODE
  28
  29         .ENTRY SEMI
  30
  31         .EXTERNAL PRMESG,YBATCH,ZOW,BEGLN
  32         MOFILE=7600
  33         XR=16
  34
  35         .RSECT SEM1
  36         FIELD 1
  37
  38 ENGOA,  TAD (-5
  39         JMS I (ZEROCD
  40         TAD I (BLKNO
  41         DCA I (7620
  42         CLA IAC
  43         DCA I (7617     /'CCBTCH' IS ON SYS:
  44         TAD (20         /   /T OPTION
  45         DCA I (7644
  46         TAD (20         /  ALSO /H (HUSH) OPTION
  47         DCA I (7643
  48         TAD (YBATCH
  49         JMP I (ZOW      /CHAIN TO BATCH
  50
  51 ZEROCD, 0
  52         TAD (-42        /AC MAY BE NON-0
  53         DCA T$
  54         TAD (MOFILE-1
  55         DCA XR
  56         DCA I XR        /ZERO THE COMMAND DECODER OUTPUT AREA
  57         ISZ T$
  58         JMP .-2
  59         JMP I ZEROCD
  60 T$:     0
  61 \fSEMSG1,        TEXT    /? ENTER ERROR/
  62 SEMSG2, TEXT    \?I/O ERROR\
  63 SEMSG3, TEXT    /?DEVICE FULL/
  64 SEMSG4, TEXT    /?CLOSE ERROR/
  65         PAGE
  66 \f       BATBUF=4400     /LOCATION OF ONE BLOCK BATCH TEMP BUFFER
  67         USR=200
  68         GLINE=1200      /LOCATION FROM KBM
  69         CTRLCK=1241     /LOC FROM KBM, PTS TO PLACE TO BRANCH ON ^C
  70 BATPTR, BATBUF-1
  71 LCHAR,  0
  72
  73 SEMGO,  CIF CDF 10
  74         JMP I SEMI
  75
  76 SEMI,   0
  77         CLA IAC         /SYS
  78         JMS I (USR
  79         3               /ENTER
  80 BLKNO,  TEMNAM
  81 BLKLEN, 0               /NEG OF LENGTH
  82         JMP SEMER1      /ENTER ERROR
  83         TAD BLKNO
  84         DCA BATBLK
  85         TAD (BEGLN-1
  86         DCA XR
  87         TAD (7600
  88         DCA I (CTRLCK   /FORCE ^C TO GLINE TO GO TO 7600
  89         JMS BATLST
  90         BATHED
  91 S2,     CDF 0
  92         TAD I XR
  93         CDF 10
  94         SNA
  95         JMP LINEND
  96         DCA LCHAR       /SAVE CHAR
  97         TAD LCHAR
  98         TAD (-";
  99         SNA CLA
 100         JMP GOTSEM
 101         TAD LCHAR
 102 S3,     JMS BATPUT
 103         JMP S2
 104 \fLINEND,        TAD LCHAR
 105         TAD (-";        /LOOK AT LAST CHAR
 106         SZA CLA         /WAS IT SEMICOLON?
 107         JMP BATEND      /NO, END OF TEMP BATCH STREAM
 108         CIF CDF 0
 109         JMS I (GLIN     /YES, READ NEW LINE FROM KEYBOARD
 110 /**** WHAT IF WE'RE RUNNING UNDER BATCH ****
 111         TAD (BEGLN-1
 112         DCA XR
 113         JMP S2
 114
 115 GOTSEM, JMS KRLF
 116         TAD (".
 117         JMP S3
 118
 119 KRLF,   0
 120         TAD (215
 121         JMS BATPUT
 122         TAD (212
 123         JMS BATPUT
 124         JMP I KRLF
 125
 126 BATPUT, 0
 127         ISZ BATPTR
 128         CDF BATBUF
 129         DCA I BATPTR
 130         CDF 10
 131         TAD BATPTR
 132         TAD (-BATBUF-377
 133         SNA CLA
 134         JMS BATWRIT     /WRITE OUT BUFFER IF FULL
 135         JMP I BATPUT
 136 \fBATWRIT,0
 137         CIF 0
 138         JMS I (7607
 139         4200            /WRITE 1 BLOCK
 140         BATBUF
 141 BATBLK, 0
 142         JMP SEMER2      /  I/O ERROR
 143         ISZ BATBLK      /POINT TO NEXT BLOCK
 144         ISZ BATLEN      /BUMP LENGTH
 145         ISZ BLKLEN
 146         SKP
 147         JMP SEMER3      /DEVICE FULL
 148         TAD (BATBUF-1
 149         DCA BATPTR
 150         JMP I BATWRIT
 151
 152 BATEND, JMS KRLF
 153         JMS BATLST
 154         BATAIL
 155         JMS BATWRIT
 156         CLA IAC         /SYS
 157         JMS I (USR
 158         4               /CLOSE
 159         TEMNAM
 160 BATLEN, 0               /LENGTH OF TEMPORARY FILE
 161         JMP SEMER4      /CLOSE ERROR
 162         JMP I (ENGOA
 163 \fBATLST,        0
 164         TAD I BATLST
 165         DCA T$
 166         ISZ BATLST
 167 L$:     TAD I T$
 168         SNA
 169         JMP I BATLST
 170         JMS BATPUT
 171         ISZ T$
 172         JMP L$
 173
 174 T$:     0
 175
 176 SEMER1, JMS I (PRMESG
 177         SEMSG1
 178 SEMER2, JMS I (PRMESG
 179         SEMSG2
 180 SEMER3, JMS I (PRMESG
 181         SEMSG3
 182 SEMER4, JMS I (PRMESG
 183         SEMSG4
 184         PAGE
 185 \f       .FSECT GLYN
 186         FIELD 0
 187
 188 GLIN,   0
 189         JMS I PGLINE
 190         CIF CDF 10
 191         JMP I GLIN
 192 PGLINE, GLINE
 193 \f       .ASECT SEMSGS
 194         .ENABLE ASCII
 195         FIELD 0
 196         *7400
 197 BATHED, TEXT    "$JOB"<215><212>"."
 198 BATAIL, TEXT ".R FOTP"<215><212>"*SYS:CCBTCH.TM/D$"<215><212>"$END"<215><212><32>
 199 TEMNAM, FILENAME CCBTCH.TM