sw/os8/v3d/sources/system/dectapes/dectape1/ASR33.PA

   1 /3 TTY HANDLER FOR BUILD
   2 /
   3 /
   4 /
   5 /
   6 /
   7 /
   8 /
   9 /
  10 /
  11 /COPYRIGHT  (C)  1974,1975,1977 BY DIGITAL EQUIPMENT CORPORATION
  12 /
  13 /
  14 /
  15 /
  16 /
  17 /
  18 /
  19 /
  20 /
  21 /
  22 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  23 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  24 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  25 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  26 /
  27 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  28 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  29 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  30 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  31 /
  32 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  33 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  34 /DIGITAL.
  35 /
  36 /
  37 /
  38 /
  39 /
  40 /
  41 /
  42 /
  43 /
  44 /
  45         *0
  46         -1
  47 DEVICE AS33;DEVICE TTY;0;1;ZBLOCK 2
  48
  49         TTYVERSION="A&77
  50
  51 /V3 FIXES:
  52
  53 /1.     NOW RECOGNIZES PARITY ^Z ON OUTPUT
  54 /2.     NOW RECOGNIZES ^Z ON OUTPUT EVEN IF NOT
  55 /       FOLLOWED BY 0'S
  56 /3.     VERSION # IS NOW 1.
  57
  58         *200
  59         /TELETYPE HANDLER - NOT VERY INTELLEGENT.
  60         /ONLY RECOGNIZES ^Z AND ^C ON INPUT
  61         /AND ^C AND ^O ON OUTPUT
  62         /OH WELL, WHAT CAN YOU EXPECT IN ONE PAGE.
  63         / THE LOGIC IS VERY SIMILIAR TO THE PTR AND PTP HANDLERS.
  64 TTY360, 360             /MUST BE FIRST LOC ON PAGE!
  65 TTY,    TTYVERSION
  66 TT7600, 7600
  67         RDF
  68         TAD TTYCIF
  69         DCA TTYXIT      /SAVE RETURN FIELD
  70         TAD I TTY
  71         AND TT70
  72         TAD TTCDF
  73         DCA TTYCDF      /DATA FIELD OF BUFFER
  74         CLA CLL CML RAR
  75         TAD I TTY
  76         AND TT3700
  77         CMA
  78         DCA TTYWC
  79         ISZ TTY
  80         TAD I TTY
  81         DCA TTYCA       /SAVE BUFFER ADDRESS
  82         ISZ TTY
  83         ISZ TTY
  84         JMP TTKLG
  85 TTYLP,  SNL CLA
  86         JMP TTYGLP      /ZER LINK MEANS READ
  87         JMS TTYTST      /TEST FOR ^C
  88         TAD TTYM14      /-203-14=-217 =-"^O"
  89         SNA CLA
  90         JMP TTYCTO
  91         TAD I TTYCA     /CHARACTER 1 IS LOW ORDER 8 BITS OF WORD 1
  92         JMS TTYPCH
  93         DCA TTYGCH
  94         ISZ TTYCA
  95 TT7400, 7400
  96         TAD I TTYCA     /CHARACTER 2 IS LOW ORDER 8 BITS OF WORD 2
  97         JMS TTYPCH
  98         CLL RTR
  99         RTR
 100         TAD TTYGCH
 101         CLL RTR
 102         RTR             /CHARACTER 3 IS HIGH ORDER 4 BITS OF WORDS 1 AND 2
 103         JMS TTYPCH      /WILL SET LINK ON!
 104 TTLOOP, ISZ TTYCA       /AC HAPPENS TO BE ZERO HERE
 105 TT70,   70
 106 TTKLG,  ISZ TTYWC
 107         JMP TTYLP
 108 TTYRTN, TAD TTYCDF
 109         CLL CIA
 110         SNL CLA
 111         ISZ TTY         /SKIP PAST ERROR RETURN
 112 TTYXIT, HLT             /RESTORE CALLING FIELDS
 113         RAL
 114         JMP I TTY
 115 TTYPCH, 0               /MUST SET LINK ON!
 116         DCA TTYTST
 117         TAD TTYTST
 118         TAD TTYM32      /ONLY CARE IF LOW ORDER 7 BITS ARE -32
 119         AND TTY177      /SO ONLY LOOK AT THESE BITS
 120         SNA CLA
 121         JMP TTYRTN      /WAS A ^Z
 122         TAD TTYTST      /GET BACK ALL 12 BITS
 123         JMS TTPRNT
 124         AND TT7400      /BUT RETURN ONLY LEFT THIRD
 125         STL             /**** CRUD
 126         JMP I TTYPCH
 127 TTY212, 212
 128         IFNZRO .-TTY360-100     <ER3700,QQQQ>
 129 TTYCA,  0
 130 TTYWC,  0
 131 TTYTST, 0
 132 TTYCDF, 0
 133         TAD TTY200
 134         KRS             /TEST FOR ^C WITH FLAG UP
 135         TAD TTM203
 136         SNA
 137         KSF
 138         JMP I TTYTST
 139 TTYCIF, CDF CIF 0
 140         JMP I TT7600
 141 TTPRNT, 0
 142         TLS
 143         TSF
 144         JMP .-1
 145         JMP I TTPRNT
 146 TTCDF,  CDF 0
 147
 148 /FOLLOWING CODE READS TTY AND PACKS IN BUFFER.
 149 TTYGLP, JMS TTYGCH
 150         DCA I TTYCA
 151 TTYM32, JMS TTYGCH
 152         DCA TTYPCH
 153         JMS TTYGCH
 154         RTL
 155         RTL
 156         DCA TTYGCH
 157         TAD TTYGCH
 158         AND TT7400
 159         TAD I TTYCA
 160 TT3700, DCA I TTYCA
 161         TAD TTYGCH
 162 TTY200, AND TTY360
 163         CLL RTL
 164         RTL             /CLEARS LINK
 165         TAD TTYPCH
 166         ISZ TTYCA
 167         DCA I TTYCA
 168         JMP TTLOOP
 169         IFNZRO .-TTY360-146 <TTYERR,QQQQQ>
 170 TTYGCH, 0               /MUST BE AT REL LOC 146
 171         TAD TTYCDF
 172 TT7700, SMA CLA
 173         JMP I TTYGCH
 174         ISZ TTYTST
 175         JMP TTYKSF
 176         TAD TTY212
 177         JMP TTECHO
 178 TTYKSF, KSF
 179         JMP .-1
 180         JMS TTYTST
 181         TAD TTM27
 182         SNA             /IS IT A ^Z?
 183         DCA TTYCDF      /YES - SET END-OF-FILE FLAG
 184         TAD TTY14
 185         DCA TTYTST      /TTYTST=-1 IF CARRIAGE RETURN
 186         KRB
 187 TTECHO, JMS TTPRNT      /ECHO THE INPUT CHARACTER
 188         JMP I TTYGCH
 189 TTM203, -203
 190 TTM27,  -27
 191 TTYM14, -14
 192 TTY177, 177
 193         IFNZRO .-TTY360-175 <NICE,QQ>
 194 TTYCTO, 6032            /SHOULD BE AT REL LOC 175 FOR PATCHERS
 195         JMP TTYRTN
 196 TTY14,  14
 197         $
 198 \f