sw/os8/v3d/sources/system/dectapes/dectape1/TD8EC.PA

   1 /4 TD8E HANDLER FOR BUILD..TD8E-C
   2 /
   3 /
   4 /
   5 /
   6 /
   7 /
   8 /
   9 /
  10 /
  11 /COPYRIGHT  (C)  1974,1975,1977 BY DIGITAL EQUIPMENT CORPORATION
  12 /
  13 /
  14 /
  15 /
  16 /
  17 /
  18 /
  19 /
  20 /
  21 /
  22 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  23 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  24 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  25 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  26 /
  27 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  28 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  29 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  30 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  31 /
  32 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  33 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  34 /DIGITAL.
  35 /
  36 /
  37 /
  38 /
  39 /
  40 /
  41 /
  42 /
  43 /
  44 /
  45         *0
  46         -2
  47 DEVICE TD8C;DEVICE DTA4;4210;4012;ZBLOCK 2
  48 DEVICE TD8C;DEVICE DTA5;4210;4016;ZBLOCK 2
  49
  50         SDSS=6751       /SKIP ON SINGLE LINE FLAG
  51         SDST=6752       /SKIP ON TIME ERROR
  52         SDSQ=6753       /SKIP ON QUAD LINE FLAG
  53         SDLC=6754       /LOAD TAPE COMMAND REGISTER
  54         SDLD=6755       /LOAD DATA REGISTER
  55         SDRC=6756       /READ COMMAND REGISTER
  56         SDRD=6757       /READ DATA REGISTER
  57
  58         TDVERSION="D&77
  59
  60 /V3 CHANGES:
  61
  62 /1.     VERSION # IS NOW 1
  63 /2.     PARITY ^C IS NOW LEGAL
  64 /3.     INITIALIZATION BUG FIXED
  65 /4.     ^C CHECK NO LONGER ADVANCES READER
  66 /MAINTENANCE RELEASE CHANGES:
  67
  68 /5.     FIXED ^C BUG
  69 /6.     MADE CODING IMPROVEMENTS
  70 /7.     FIXED RETRY BUG
  71
  72
  73
  74         *200
  75
  76 NXINIT, 7600    /CLEAR AC HERE!!!
  77         JMS I CINIT2    /PART OF INITIALIZATION..DO THE PART
  78 BASE2,  DCA JINIT       /ON SECOND PAGE AND THEN TO JINIT
  79         JMP JINIT
  80 CRDQAD, R4LINE-BASE
  81 CINIT2, INIT2-BASE
  82 CSELCT, SELECT-BASE
  83 CXUNIT, XUNIT-BASE
  84
  85 BUFF,   4000            /V3
  86 PGCT,   0
  87
  88 DTA0,   TDVERSION       /ENTRY FOR UNIT 0
  89         CLA CLL
  90         JMP DTA1X
  91 UNIT,   0               /FILLER WORD
  92 DTA1,   TDVERSION       /ENTRY FOR UNIT 1
  93         CLA CLL CML
  94         TAD DTA1
  95         DCA DTA0        /PICK UP ARGS AT DTA0
  96 DTA1X,  RAR
  97         DCA UNIT        /UNIT # FROM LINK
  98         RDF
  99         TAD C6203
 100         DCA LEAVE       /SET UP EXIT FROM HANDLER
 101 JINIT,  JMP INIT
 102         TAD I DTA0
 103         DCA FUNCT       /SAVE FUNCTION WORD
 104         TAD FUNCT
 105         CLL RAL
 106 C200,   AND CM200       /GET A PAGE COUNT
 107         DCA PGCT
 108         TAD FUNCT
 109 C374,   AND C70         /ISOLATE FIELD OF TRANSFER
 110         TAD C6203
 111         DCA XFIELD
 112         ISZ DTA0        /POINT TO BUFFER
 113         TAD I DTA0
 114         DCA BUFF
 115         ISZ DTA0        /POINT TO RECORD
 116         TAD I DTA0
 117         CLL RAL         /CONVERT TO DECTAPE BLOCKS
 118         DCA TBLOCK
 119         ISZ DTA0        /POINT TO ERROR RET.
 120 C6203,  CIF CDF 0
 121 \f
 122         CLA CLL CMA RTL
 123         DCA ERCNT       /3 ERROR TRIES
 124         TAD UNIT
 125         DCA I CXUNIT
 126         JMS I CSELCT    /CHECK FOR SELEC ERROR
 127         JMP .-1         /LOOPS IF NO ^C AND SELECT ERROR
 128         TAD FUNCT
 129         CLL RAR
 130         JMP GO          /OK.. START THE SEARCH
 131 TRWCOM, SDST            /TIME OR CHECK SUM ERROR?
 132         SZA CLA
 133         JMP TRY3        /YES TRY UP TO 3 TIMES
 134         TAD PGCT        /NO.. IS PAGE COUNT EXHAUSTED?
 135         TAD CM200
 136         SNA
 137         JMP EXIT        /YES.. DONE THIS TRANSFER
 138         DCA PGCT        /NEW PAGE COUNT
 139         ISZ TBLOCK
 140         TAD BUFF
 141         TAD C200        /GET NEW BUFFER ADDRESS
 142         DCA BUFF
 143         CLL CML         /FORCE FORWARD MOTION
 144 GO,     CLA CML RTR     /PUT IN DIRECTION BIT
 145         TAD C1000
 146         TAD UNIT
 147         SDLC            /INITIATE THE MOTION
 148         JMS I CRDQAD    /WAIT FOR 8 LINES TO PASS
 149         JMS I CRDQAD
 150 M20,    7760            /DON'T CARE IF IT DOES SKIP!!!
 151 TSRCH,  SDSS            /WAIT\ f FOR BLOCK MARK OR END ZONE
 152         JMP .-1
 153         SDRC
 154         CLL RTL         /DIRECTION TO LINK, DATA TO AC 4-9
 155         AND C374        /ISOLATE M.T BITS
 156         TAD M110        /IS IT END ZONE?
 157         SNA
 158         JMP ENDZ        /YES..DO SOMETHING REASONABLE
 159         TAD M20         /HOW ABOUT BLOCK MARK?
 160         SZA CLA
 161         JMP TSRCH       /NEITHER..KEEP LOOKING
 162         SDRD            /WHAT IS THIS BLOCK'S #?
 163         SZL             /IF IN REVERSE, LOOK FOR 3 BEFORE
 164         TAD TC3         /THE ACTUAL TARGET BLOCK
 165         CMA
 166         TAD TBLOCK
 167         CMA
 168         SNA             /IS THIS THE BLOCK?
 169         JMP TFOUND      /YES..HAVE CORRECT ONE
 170 M110,   SZL SNA CLA     /ARE WE HEADED PROPERLY?
 171         JMP TSRCH       /YES.. KEEP LOOKING
 172 ENDZ,   SDRC            /IF WE ARE IN END ZONE FORWARD, WE LOSE
 173         CLL RTL
 174         JMP GO          /EXECUTE TURN AROUND AND SEARCH
 175 \fTRY3,  CLA CLL         /V3C
 176         ISZ ERCNT       /TRIED 3 TIMES?
 177         JMP GO
 178         JMP FATAL
 179 EXIT,   ISZ DTA0        /NORMAL RETURN
 180         CLL CML
 181 FATAL,  TAD UNIT        /STOP TAPE FIRST
 182         SDLC
 183         CLA CML RAR     /EITHER 0 OR 4000 IN AC
 184 LEAVE,  HLT     /GETS CIF CDF N
 185         JMP I DTA0
 186
 187 INIT,   JMS .           /FIND OUT WHERE WE GOT LOADED
 188 BASE,   TAD CRDQAD
 189         SPA             /NEGATIVE ENDS LIST
 190         JMP NXINIT
 191         TAD INIT
 192         DCA CRDQAD
 193         ISZ .-1
 194         ISZ BASE
 195         JMP BASE
 196
 197 FUNCT,  0
 198 C1000,  1000
 199
 200         *367
 201 TFOUND, SZL CLA         /ARE WE IN RIGHT DIRECTION
 202         JMP GO          /NOT YET
 203         TAD FUNCT
 204         CLL RAL         /R/W TO LINK
 205         CLA
 206 C70,    70
 207 TC3,    3
 208         TAD BUFF
 209 XFIELD, HLT             /CONTROL 'TRICKLES THROUGH
 210
 211 TBLOCK=DTA1
 212 ERCNT=INIT+1
 213 CM200=NXINIT
 214 DTA2=DTA0
 215 DTA3=DTA1
 216 DTA4=DTA0
 217 DTA5=DTA1
 218 DTA6=DTA0
 219 DTA7=DTA1
 220 \f       *400
 221         CIF 0           /WE ARE IN FIELD 0
 222         DCA XBUFF
 223         RAR
 224         DCA XFUNCT      /READ/WRITE TO FUNCTION
 225 RGRD,   SDSS
 226         JMP .-1         /LOOK FOR REVERSE GUARD PATTERN
 227         SDRC
 228         AND K77
 229         TAD CM32
 230         SZA CLA         /IF NOT REV. GUARD, KEEP LOOKING
 231         JMP RGRD
 232         TAD C7600
 233         DCA WORDS       /128 WORDS/BLOCK
 234         TAD XFUNCT
 235 K7700,  SMA CLA         /IS IT READ OR WRITE?
 236         JMP TREAD
 237         SDRC            /CHECK FOR WRITE LOCKOUT
 238         AND TC300
 239         CLL             /SETUP TO RETRY IF WRITE LOCK
 240         SZA CLA
 241         JMP I CTRY3     /IF LOCKED OUT, ERROR
 242         JMS R4LINE      /SKIP A WORD
 243 C7600,  7600            /CLA
 244         TAD C1400
 245         TAD XUNIT
 246         SDLC            /TURN ON WRITE HEAD
 247         CLA CMA
 248         JMS W4LINE      /7777 IN REV. CHECKSUM
 249         CLA CMA
 250         DCA CSUM        /AND ALSO TAPE CHECKSUM
 251 WRTLP,  TAD I XBUFF
 252         JMS W4LINE
 253         ISZ XBUFF       /INCREMENT BUFF. ADD.
 254 K77,    77
 255         ISZ WORDS       /DONE A BLOCK?
 256         JMP WRTLP
 257         JMS W4LINE      /A 129 TH WORD OF 0
 258         JMS GCHK        /GET 6 BIT CHECKSUM
 259         JMS W4LINE      /WRITE IT TO TAPE
 260         JMS W4LINE      /LET CHECK SUM FINISH
 261         JMP I CRWCOM    /SEE IF WE ARE FINISHED
 262 \f
 263 TREAD,  JMS R4LINE
 264         JMS R4LINE      /SKIP CONTROL WORDS
 265         JMS R4LINE
 266         AND K77         /CHECKSUM
 267         TAD K7700
 268         DCA CSUM
 269 RDLP,   JMS R4LINE
 270         JMS EFUN        /ADD WORD TO CHECKSUM
 271         DCA I XBUFF
 272         ISZ XBUFF
 273 TC300,  300
 274         ISZ WORDS       /DONE BLOCK?
 275         JMP RDLP
 276         JMS R4LINE
 277         JMS EFUN        /CHECK SUM 129 TH WORD
 278         JMS R4LINE
 279         AND K7700       /READ CHECKSUM
 280         JMS EFUN
 281         JMS GCHK        /COMPARE TAPE AND OUR CHECKSUM
 282         JMP I CRWCOM
 283
 284 W4LINE, 0               /ADD TO CHECKSUM AND WRITE A 12 BIT
 285         JMS EFUN        /WORD
 286         SDSQ
 287         JMP .-1         /SKIP ON QUAD LINE FLAG
 288         SDLD
 289         CLA             /AC IS NOT CLEARED AFTER SDLD
 290         JMP I W4LINE
 291
 292 R4LINE, 0               /WAIT FOR QUAD FLAG AND READ
 293         SDSQ
 294         JMP .-1
 295         SDRD
 296         JMP I R4LINE
 297
 298 EFUN,   0               /COMPUTE EQUIVALENCE CHECKSUM
 299         CMA
 300         DCA ETMP        /ACTUALLY CHECKSUMS ON DECTAPE ARE
 301         TAD ETMP        /EQUIVALENCE OF ALL WORDS IN A RCORD
 302         AND CSUM        /6 BITS AT A TIME. SINCE EQUIVALENCE
 303         CIA             /IS ASSOCIATIVE WE DO IT 12 AT A TIME
 304         CLL RAL         /AND CONDENSE LATER.
 305         TAD ETMP        /IDENTITIES USED ARE:
 306         TAD CSUM        /A+B=(A.XOR.B)+2*(A.AND.B)
 307         DCA CSUM        /A.EQU.B=.NOT.(A.XOR.B)=A.XOR.(.NOT.B)
 308         TAD ETMP        /A.EQU.B=(A+(.NOT.B))-2*(A.AND.(.NOT.B))
 309         CMA
 310         JMP I EFUN
 311
 312 \fGCHK,  0               /FORM 6 BIT CHECKSUM
 313         CLA
 314         TAD CSUM
 315         CLL CMA RTL
 316         RTL
 317         RTL
 318         JMS EFUN
 319         CLA CLL CML
 320         TAD CSUM
 321         AND K7700
 322         JMP I GCHK
 323
 324 INIT2,  0               /TIS INITIALIZES LOCS IN PAGE 2
 325 INIT3,  TAD CTRY3
 326         SNA
 327         JMP I INIT2     /0 ENDS LIST
 328         TAD INIT2
 329         DCA CTRY3       /UPDATE THE LIST
 330         ISZ .-1
 331         ISZ INIT3
 332         JMP INIT3
 333
 334 CTRY3,  TRY3-BASE2
 335 CRWCOM, TRWCOM-BASE2
 336 XBUFF,  0               /0 MUST TERMINATE IT!!
 337 CM32,   -32
 338 C1400,  1400
 339
 340 SELECT, 0               /THIS ROUTINE CHECKS FOR SELECT
 341         TAD XUNIT       /AND ^C TYPED
 342         SDLC
 343         SDRC            /GET STATUS AND SEE IF SELECT ERROR ON
 344         AND C100
 345         SNA CLA
 346         ISZ SELECT      /NOPE .TAKE NORMAL OUT
 347         KSF             /SEE IF FLAG IS UP
 348         JMP I SELECT    /NO..EXIT
 349         TAD C7600
 350         KRS
 351         TAD (-7603      /IS IT ^C?
 352         SZA CLA
 353         JMP I SELECT    /NO..EXIT
 354         JMP I C7600
 355
 356 C100,   100
 357
 358 XFUNCT=INIT2
 359 CSUM=XFUNCT+1
 360 WORDS=CSUM+1
 361 ETMP=WORDS+1
 362 XUNIT=ETMP+1
 363 $$$$$$$
 364 \f