sw/os8/v3d/sources/system/dectapes/dectape2/DF32SY.PA

   1 /2 DF32 SYSTEM HANDLER
   2 /
   3 /
   4 /
   5 /
   6 /
   7 /
   8 /
   9 /
  10 /
  11 /COPYRIGHT  (C)  1974,1975 BY DIGITAL EQUIPMENT CORPORATION
  12 /
  13 /
  14 /
  15 /
  16 /
  17 /
  18 /
  19 /
  20 /
  21 /
  22 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  23 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  24 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  25 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  26 /
  27 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  28 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  29 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  30 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  31 /
  32 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  33 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  34 /DIGITAL.
  35 /
  36 /
  37 /
  38 /
  39 /
  40 /
  41 /
  42 /
  43 /
  44 /
  45 \f/MAINTENANCE RELEASE CHANGES:
  46
  47 /1.     TOOK OUT SOFSET
  48
  49 DF32=1
  50         RF08=0
  51         VERSION="B&77
  52
  53         *0
  54         -1
  55         DEVICE DF32;DEVICE SYS;4124;2007;0;177
  56
  57         STARTB-ENDB-1
  58
  59         NOPUNC
  60         *6604
  61         ENPUNC
  62
  63 STARTB, NOP             /FOR "SWAP"
  64 B6653,  6653
  65 B7647,  7647
  66 B7577,  7577
  67 B200,   200
  68 B7605,  7605
  69 B7751,  7751
  70         ZBLOCK  6622-.
  71         TAD I B6653
  72         CDF 10
  73         DCA I B7647
  74         CDF 0
  75         ISZ B6653
  76         ISZ B7647
  77         JMP .-6         /MOVE FIELD 1 RESIDENT UP
  78         IFNZRO  RF08    <6643>
  79         6615
  80         7600
  81         TAD B7577
  82         DCA I B7751
  83         TAD B200
  84         6603            /NOW READ IN FIELD 0 RESIDENT FROM RECORD 1/2
  85
  86         IFNZRO  RF08    <6623>
  87         IFNZRO  DF32    <6622>
  88         JMP .-1
  89         6621
  90         IFNZRO  RF08    <SKP>
  91         HLT             /ERROR READING SYSTEM IN
  92 ENDB,   JMP I B7605
  93 \f       /BOOTSTRAP FOR DISK MONITOR IS AS FOLLOWS:
  94
  95         /       LOCATION        CONTENTS
  96         /       7750            7600
  97         /       7751            6603
  98         /       7752            6622
  99         /       7753            5352
 100         /       7754            5752
 101 \f       *200
 102
 103         NOPUNCH
 104         *7600
 105         ENPUNCH
 106
 107         ZBLOCK 7
 108 SHNDLR, VERSION
 109         CLA CLL CMA RTL /-3
 110         DCA SYSCNT              /# TRYS ON ERROR
 111         TAD I SHNDLR
 112         RAL
 113         CLA RTL
 114         TAD S6603
 115         DCA SFUN        /EITHER A READ OR WRITE
 116         TAD I SHNDLR
 117         AND S70
 118         DCA SFIELD      /GET FIELD OF BUFFER
 119         TAD I SHNDLR
 120         RAL
 121         AND S7600
 122         CIA
 123         DCA SWC         /SET UP WORD COUNT
 124         CLA CMA
 125         ISZ SHNDLR
 126         TAD I SHNDLR
 127         DCA SCA         /BUFFER ADDRESS-1
 128         ISZ SHNDLR
 129         IFNZRO  DF32 <
 130         TAD I SHNDLR
 131         RTL
 132         AND S3700>
 133         TAD SFIELD
 134         6615            /LOAD DISK EXTENDED MEMORY
 135 S7600,  7600
 136         IFNZRO RF08 <
 137         TAD I SHNDLR
 138         RTR
 139         RTR
 140         AND S377
 141         6643            /LOAD HIGH ORDER>
 142         TAD I SHNDLR
 143         RTR
 144         RTR
 145         RAR
 146         AND S7400
 147 SFUN,   HLT             /BECOMES DISK IOT.(READ OR WRITE)
 148         RDF
 149         TAD SCIF
 150         DCA SFIELD
 151         IFNZRO  DF32    <6622>
 152         IFNZRO  RF08    <6623>
 153         JMP .-1
 154         ISZ SHNDLR
 155         6621            /SKIP ON ERROR
 156         IFNZRO RF08 <SKP        /SENSE OF SKIP IS REVERSED>
 157         JMP SYSER
 158         ISZ SHNDLR
 159 SFIELD, HLT             /RETURN TO PROPER FIELD
 160         6601            /CLEAR TROUBLESOME FLAG
 161         JMP I SHNDLR
 162         ZBLOCK 2
 163 SYSER,  CLA CLL CML RAR /4000
 164         ISZ SYSCNT      /TRY AGAIN?
 165         SKP CLA
 166         JMP SFIELD      /WHY BOTHER
 167         CLA CLL CMA RTL
 168         TAD SHNDLR
 169         DCA SHNDLR      /RESET PARAMETERS AND TRY AGAIN
 170         IFNZRO RF08     <IFNZRO .-7700  <NZERR>;        SKP;    HLT>
 171         JMP SHNDLR+3
 172 SCIF,   CIF 0
 173 SYSCNT, 0
 174         IFNZRO DF32     <IFNZRO .-7700  <NZERR>;        SKP;    HLT>
 175 S6603,  6603
 176 S70,    70
 177 S7400,  7400
 178         IFNZRO  DF32 <S3700,    3700>
 179         IFNZRO RF08 <S377,      377>
 180         SCA=7751
 181         SWC=7750
 182         $
 183 \f