sw/os8/v3d/sources/system/dectapes/dectape3/LINCNS.PA

   1 /1 LINCTAPE HANDLER FOR BUILD
   2 /
   3 /
   4 /
   5 /
   6 /
   7 /
   8 /
   9 /
  10 /
  11 /COPYRIGHT  (C)  1974,1975 BY DIGITAL EQUIPMENT CORPORATION
  12 /
  13 /
  14 /
  15 /
  16 /
  17 /
  18 /
  19 /
  20 /
  21 /
  22 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  23 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  24 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  25 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  26 /
  27 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  28 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  29 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  30 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  31 /
  32 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  33 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  34 /DIGITAL.
  35 /
  36 /
  37 /
  38 /
  39 /
  40 /
  41 /
  42 /
  43 /
  44 /
  45         *0
  46         -10
  47 DEVICE LNC;DEVICE LTA0;4170;10;ZBLOCK 2
  48 DEVICE LNC;DEVICE LTA1;4170;11;ZBLOCK 2
  49 DEVICE LNC;DEVICE LTA2;4170;12;ZBLOCK 2
  50 DEVICE LNC;DEVICE LTA3;4170;13;ZBLOCK 2
  51 DEVICE LNC;DEVICE LTA4;4170;14;ZBLOCK 2
  52 DEVICE LNC;DEVICE LTA5;4170;15;ZBLOCK 2
  53 DEVICE LNC;DEVICE LTA6;4170;16;ZBLOCK 2
  54 DEVICE LNC;DEVICE LTA7;4170;17;ZBLOCK 2
  55
  56         LINCVERSION="A&77
  57
  58         *200
  59         /LINCTAPE HANDLER FOR PS/8 - CRUDE VERSION (WRITE OPERATION CHECKS
  60         /AFTER EACH BLOCK)
  61         /ALL 8 HANDLERS ARE IN THIS PAGE - SEE DECTAPE HANDLER FOR
  62         /DUMB COMMENT
  63
  64         /PDP-12 OPCODES NEEDED
  65         LINC=   6141
  66         PDP=    0002
  67         CLR=    0011
  68         AXO=    0001
  69         TMA=    0023
  70         TAC=    0003
  71         STDI=   0436
  72         COM=    0017
  73         ROLI1=  0261
  74         ESF=    0004
  75
  76 LTM203, -203
  77 LTA,    0
  78 LTA7,   7
  79 LTA30,  30
  80 LTA70,  70
  81 LTA702, 702
  82 LT3700, 3700
  83 LTATMP, LINCVERSION
  84 DTA0,   ISZ LTANO
  85 DTA1,   ISZ LTANO
  86 DTA2,   ISZ LTANO
  87 DTA3,   ISZ LTANO
  88 DTA4,   ISZ LTANO
  89 DTA5,   ISZ LTANO
  90 DTA6,   ISZ LTANO
  91 DTA7,   ISZ LTANO
  92 LTA200, 200
  93         TAD LTANO
  94         CMA
  95         TAD LTATAD
  96         DCA LTANO
  97         CLA CLL CML RTR
  98         TAD LTANO
  99         DCA LTADCA
 100         RDF
 101         TAD LCDIF0
 102         DCA LTAXIT
 103 LTANO,  0
 104         DCA LTA
 105         TAD LTAISZ
 106 LTADCA, 0
 107         TAD I LTA
 108         DCA LTARG1
 109         ISZ LTA
 110         TAD I LTA
 111         DCA LTARG2
 112         ISZ LTA
 113         TAD I LTA
 114         CLL RAL /MOVE ARGUMENTS TO WORK AREA
 115         DCA LTARG3
 116         ISZ LTA
 117         ISZ LTA
 118         TAD LTARG1      /GET CORE FIELD
 119         AND LTA70
 120         TAD LTCDF
 121         DCA LTSET
 122         TAD LTSET
 123         AND LTA70
 124         CLL RTL
 125         RTL             /MOVE TO BITS 0-2. CONTROLLER
 126         RTL             /WANTS THEM THERE
 127 SLTARG3,DCA LTATMP
 128         TAD LTANO       /GET UNIT NO.
 129         AND LTA7
 130         CLL RAR
 131         TAD LTATMP
 132         TAD LTA30       /SET BIT 7 ON. EXTENDED ADD. MODE
 133         LINC
 134         AXO             /SEND DATA TO CONTROLLER
 135         PDP
 136 LT7600, 7600
 137         DCA LTANO       /RESET UNIT NO.
 138         TAD LTARG1
 139         RTL
 140         AND LTA3
 141         CLL RTL
 142         TAD LTA702      /ADD TAPE INST; STORE IT
 143         DCA LTINST
 144 LTALP,  TAD LTARG2      /CORE ADDRESS TO CONTROLLER
 145 LTATAD, TAD LTA200      /SAVE 129 TH WORD
 146         DCA LTATMP
 147 LTSET,  0
 148         TAD I LTATMP
 149         DCA LTASVC      /SAVE LOC.
 150         TAD LTARG2
 151         LINC
 152         TMA
 153 LTINST, 0               /TAPE INSTRUCTION HERE
 154 LTARG3, 0               /BLOCK NO. HERE
 155 LTAWLP, PDP
 156         CLA
 157         TAD LTASVC      /RESTORE 129TH WORD
 158         DCA I LTATMP
 159         TAD LTA200      /ADD 200 FOR PARITY TTY
 160         KRS
 161         TAD LTM203      /TEST FOR ^C
 162         SNA CLA
 163         KSF             /IS FLAG UP?
 164         JMP NOTFUG      /EITHER NOT ^C OR NO FLAG
 165         TAD LTA30
 166         LINC
 167         ESF
 168         PDP
 169 LT7700, 7700
 170         TAD LTASVC
 171         DCA I LTATMP
 172 LCDIF0, CDF CIF 0
 173         JMP I LT7600
 174 NOTFUG, LINC
 175         STDI
 176         COM
 177         ROLI1
 178 LTA3,   TAC
 179         PDP
 180         SNL
 181         JMP LTAWLP
 182 LTADUN, CLL IAC
 183         CLA IAC RTL
 184         AND LTINST
 185         SNA CLA
 186         JMP LTALP
 187 LTNERR, TAD LTARG1
 188         AND LT3700
 189         TAD LT7700
 190         SNA             /ALL DONE?
 191         JMP LTAXIT
 192         DCA LTARG1      /NO.. SAVE COUNT
 193         TAD LTATMP
 194         DCA LTARG2
 195         ISZ LTARG3
 196         JMP LTALP
 197 LTAXIT, HLT
 198         JMP I LTA
 199 LTAISZ, ISZ LTANO
 200 LTARG1, 0
 201 LTARG2, 0
 202 LTCDF,  CDF 0
 203 LTASVC=LTADCA
 204 $$$$$$$$
 205 \f