sw/os8/v3d/sources/system/dectapes/dectape3/LINCSY.PA

   1 /2 LINCTAPE SYSTEM HANDLER
   2 /
   3 /
   4 /
   5 /
   6 /
   7 /
   8 /
   9 /
  10 /
  11 /COPYRIGHT  (C)  1974,1975,1977 BY DIGITAL EQUIPMENT CORPORATION
  12 /
  13 /
  14 /
  15 /
  16 /
  17 /
  18 /
  19 /
  20 /
  21 /
  22 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  23 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  24 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  25 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  26 /
  27 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  28 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  29 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  30 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  31 /
  32 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  33 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  34 /DIGITAL.
  35 /
  36 /
  37 /
  38 /
  39 /
  40 /
  41 /
  42 /
  43 /
  44 /
  45 \f/      SOFSET=7747
  46         SBLOCK=7776
  47         LINC=6141
  48         AXO=1
  49         PDP=2
  50         TMA=23
  51         *0
  52
  53         VERSION="B&77
  54
  55         -2
  56         DEVICE LINC;DEVICE SYS;4171;2007;0;1341
  57         DEVICE LINC;DEVICE LTA0;4171;1007;0;1341
  58
  59 /V3D:   REMOVED 'SOFSET'
  60 \f       STARTB-ENDB-1
  61
  62         NOPUNCH
  63         *7600
  64         ENPUNCH
  65
  66 STARTB, ZBLOCK 16
  67 B4047,  4047
  68 B7647,  7647
  69         1020;20;4               /IO PRESET
  70         1020;20;AXO     /LOAD SOME LINCTAPE FLAGS
  71         1020;7600;TMA   /LOAD MEMORY ADDRESS
  72         720;1           /READ RECORD 1
  73         PDP             /BACK TO PDP-8 MODE
  74         CLA
  75         TAD I B4047
  76         CDF 10
  77         DCA I B7647
  78         CDF 00
  79         ISZ B4047
  80         ISZ B7647
  81         JMP .-6
  82         JMP I .+1
  83 ENDB,   7605
  84
  85
  86
  87         /THE BOOTSTRAP FOR A LINCTAPE SYSTEM IS AS FOLLOWS:
  88
  89         /LEFT SWITCHES=700,RIGHT SWITCHES=0
  90         /I-O PRESET IN LINC MODE AND PRESS "D0". TAPE WILL MOVE
  91         /WHEN TAPE STOPS PRESS "START 20".
  92 \f       *200
  93
  94         NOPUNCH;*7600;ENPUNCH
  95
  96         ZBLOCK 7
  97 SHNDLR, VERSION
  98 S7600,  7600
  99         RDF
 100         TAD SCIF
 101         DCA SXIT
 102         TAD I SHNDLR
 103         DCA SFUN        /FUNCTION
 104         ISZ SHNDLR
 105         TAD I SHNDLR
 106         DCA SADR        /BUFFER ADDRESS
 107         ISZ SHNDLR
 108         TAD I SHNDLR
 109 /V3D    TAD SOFSET      /SOFSET=0
 110         NOP             /SAVE ROOM
 111         CLL RAL
 112         DCA SBLOK       /BLOCK NO.
 113         ISZ SHNDLR
 114         CLL CML RAR
 115         AND SFUN
 116         RTL
 117         RTL
 118         TAD S702        /GET FUNCTION;CREATE READ OR WRITE
 119         DCA SINST       /READ OR WRITE INSTRUCTION.
 120         TAD SFUN
 121         AND S70         /FIELD BITS TO AC 0-2
 122         TAD SADCDF
 123         DCA SADSET
 124         TAD SADSET
 125         AND S70
 126         RTL
 127         IAC RTL         /SET EXTENDED ADDRESS
 128         RTL
 129         LINC
 130         AXO
 131         PDP
 132         CLA
 133         TAD SFUN
 134         RAL
 135         AND S7600
 136         DCA SFUN
 137 SADSET, 0
 138 SLOOP,  CLA CLL CMA RTL
 139         DCA SERRCT      /NO. ERROR TRIES
 140 STRY,   TAD SADR
 141         TAD S200
 142         DCA SADNXT
 143         TAD I SADNXT
 144         DCA SADSVC
 145         TAD SADR
 146         LINC
 147         TMA             /CORE ADDRESS TO CONTROL
 148 SINST,  0               /READ OR WRITE
 149 SBLOK,  0               /BLOCK NO. HERE
 150         PDP
 151         CMA             /CHECKSUM HERE. 7777=GOOD
 152         DCA SADSET
 153         TAD SADSVC
 154         DCA I SADNXT
 155         IFNZRO .-7700 <NZERR>
 156         SKP
 157         HLT
 158         TAD SADSET
 159         SZA CLA
 160         JMP SERR
 161 SOK,    ISZ SBLOK
 162         TAD SADNXT
 163         DCA SADR
 164         TAD SFUN
 165         TAD S7600
 166         SNA             /ALL DONE?
 167         JMP SDONE       /YES
 168         DCA SFUN
 169         JMP SLOOP
 170 SERR,   TAD SINST
 171         RTR;RTR
 172         SPA CLA         /WAS IT READ?
 173         JMP SOK         /NO..WRITE. CONTINUE
 174         ISZ SERRCT      /READ..RETRY IT?
 175         JMP STRY
 176         CLA CLL CML RAR /DON'T BOTHER
 177         SKP
 178 SDONE,  ISZ SHNDLR
 179 SXIT,   0
 180         JMP I SHNDLR
 181 SFUN,   0
 182 SADR,   0
 183 SERRCT, 0
 184 S702,   702
 185 S200,   200
 186 S70,    70
 187 SCIF,   CDF CIF 0
 188 SADCDF, CDF 0
 189 SADNXT, 0
 190 SADSVC, 0
 191         $
 192 \f