C    APFELMAENNCHEN-PROGRAMM, 30.NOV.2004 PHILIPP HACHTMANN
C
C
       COMPLEX C,Z,CTMP
C
       REAL 
     + XIN1,XIN2,YIN1,YIN2,LOWX,LOWY,HIGHX,HIGHY,
     + XSTEP,YSTEP,MAXVAL,TEMP,
     + X,Y
C
       INTEGER 
     + MAXI,COUNT,WIDTH,
     + CR,LF,POSI,NEGA
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C                        KONSTANTE WERTE
C
C   (32=LEERZEICHEN, 88=X)
C
       CR=13
       LF=10
       POSI=88
       NEGA=46
C
CCCCCC SEITENBREITE:
       WIDTH=70
C
CCCCCC MAXIMALE ITERATIONSTIEFE
       MAXI=100
C
CCCCCC AUSSTIEGSWERT
       MAXVAL=2.0
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C                        BILDDATEN 
C
       XIN1 = -1.50
       XIN2 =  0.50
C
       YIN1 = -1.00
       YIN2 =  1.00
C
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C                        STARTMELDUNG
  100  WRITE(1,10)
   10  FORMAT(40HMANDELBROT 30.NOV.2004 PHILIPP HACHTMANN )
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C                        STARTWERTE ENDGUELTIG FESTLEGEN
C
C      EVENTUELL STARTWERTE TAUSCHEN
C
CCCCCC WENN XIN2 GROESSER IST OK, ANSONSTEN TAUSCHEN
  150  I F(XIN2.GT.XIN1) GO TO 200
       TEMP = XIN1
       XIN1 = XIN2
       XIN2 = TEMP
C       
CCCCCC WENN YIN2 GROESSER IST OK, ANSONSTEN TAUSCHEN
  200  IF(YIN2.GT.YIN1) GO TO 201
       TEMP = YIN1
       YIN1 = YIN2
       YIN2 = TEMP
C
CCCCCC WERTE UEBERNEHMEN
  201  LOWX  = XIN1
       HIGHX = XIN2
       LOWY  = YIN1
       HIGHY = YIN2
C
CCCCCC SCHRITTWEITEN AUSRECHNEN
       XSTEP = (HIGHX-LOWX)/FLOAT(WIDTH)
       YSTEP = 2.0 * XSTEP
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C                        STARTWERTE AUSGEBEN
C
       WRITE  (1,20)
   20  FORMAT (9HSETTINGS:)
       WRITE  (1,30) LOWX, HIGHX
   30  FORMAT (12HX-WERTE VON ,1F8.5,5H BIS ,1F8.5)
       WRITE  (1,40) LOWY, HIGHY
   40  FORMAT (12HY-WERTE VON ,F8.5,5H BIS ,F8.5)     
       WRITE  (1,50) MAXI, MAXVAL, XSTEP, YSTEP, WIDTH
   50  FORMAT (   4HMAX:,I3,
     +        8H MAXVAL:,F8.5,
     +         7H XSTEP:,F8.5,
     +         7H YSTEP:,F8.5,
     +         7H WIDTH:,I2)
C
       PAUSE 1 
C
CCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCCC
C                        EIGENTLICHE BERECHNUNG
C
CCCCCC EINSTIEG IN BERECHNUNG
       X=LOWX
       Y=HIGHY
C     
CCCCCC EINSTIEG IN DEN AKTUELLEN PUNKT
  300  C=CMPLX(X,Y)
       COUNT=0
       Z=(0.0,0.0)
C
CCCCCC HIER DER ITERIERTE TEIL
  400  CTMP=Z*Z
       Z=CTMP+C
       IF ((CABS(Z)).GE.MAXVAL) GO TO 410
       COUNT=COUNT+1
       IF (COUNT.GE.MAXI)     GO TO 420
       GO TO 400
C
CCCCCC PUNKT DURCHGEFALLEN       
  410   CALL PCHAR(NEGA)
        GO TO 500
C
CCCCCC PUNKT HAT MAXI ERREICHT
  420   CALL PCHAR(POSI)
C
C
CCCCCC NEUEN PUNKT MACHEN
  500  X = X + XSTEP
CCCCCC ZEILE NOCH NICHT VOLL?
       IF (X.LT.HIGHX) GO TO 300
CCCCCC X AN ANFANG SETZTEN, CR+LF DRUCKEN
       X = LOWX
       CALL PCHAR(CR)
       CALL PCHAR(LF)
CCCCCC Y WEITERRUECKEN - NEGATIV WEIL WIR VON OBEN KOMMEN
       Y=Y-YSTEP
       IF (Y.GT.LOWY) GO TO 300
C
CCCCCC HIER IST DAS BILD FERTIG.       
       WRITE(1, 60)
   60  FORMAT (6HFERTIG)
C
CCCCCC KURZE PAUSE, DANN NEUSTART
       PAUSE 7
       GO TO 100
       END
$0