* OCT - TYPE OCTAL VALUE ON THE ASR
* 
* TYPE OUT THE VALUE IN A. A STAYS UNCHANGED AFTERWARDS
*
	SUBR	OCT,OCT6	PRINT OCTAL VALUE WITH 6 DIGITS + CR/LF
	SUBR	OCTN,N6		PRINT OCTAL VALUE WITH 6 DIGITS
* 
	SUBR	OCTN1,N1	PRINT OCTAL, 1 DIGIT
	SUBR	OCTN2,N2	PRINT OCTAL, 2 DIGITS
	SUBR	OCTN3,N3	PRINT OCTAL, 3 DIGITS
	SUBR	OCTN4,N4	PRINT OCTAL, 4 DIGITS
	SUBR	OCTN5,N5	PRINT OCTAL, 5 DIGITS
	SUBR	OCTN6,N6	PRINT OCTAL, 6 DIGITS
	SUBR	OCT1   		PRINT OCTAL, 1 DIGIT
	SUBR	OCT2   		PRINT OCTAL, 2 DIGITS
	SUBR	OCT3   		PRINT OCTAL, 3 DIGITS
	SUBR	OCT4   		PRINT OCTAL, 4 DIGITS
	SUBR	OCT5   		PRINT OCTAL, 5 DIGITS
	SUBR	OCT6   		PRINT OCTAL, 6 DIGITS
* 
	SUBR	TP	TYPE OUT LETTER IN A
	SUBR	CR	PRINT CR
	SUBR	LF	PRINT LF
	SUBR	SP	PRINT A SPACE CHARACTER
	SUBR	NL	PRINT CR/LF
	SUBR	TYPE,TEXT
*  
* 
********************************************************************************
*       
	REL
	ORG	0
* 
********************************************************************************
* 
* 
TP	DAC	0
	SKS	'104
	JMP	*-1
	OCP	'104
	OTA	'4	TYPE ON ASR
	JMP	*-1
	SKS	'4
	JMP	*-1
	JMP*	TP	RETURN
* 
* 
********************************************************************************
* 
OCT6	DAC	0
	JST	N6
	JST	NL
	JMP*	OCT6
OCT5	DAC	0
	JST	N5
	JST	NL
	JMP*	OCT5
OCT4	DAC	0
	JST	N4
	JST	NL
	JMP*	OCT4
OCT3	DAC	0
	JST	N3
	JST	NL
	JMP*	OCT3
OCT2	DAC	0
	JST	N2
	JST	NL
	JMP*	OCT2
OCT1	DAC	0
	JST	N1
	JST	NL
	JMP*	OCT1
* 
********************************************************************************
* 
N1	DAC	0
	JST	SAVE
	LDA	=-6
	JMP	NGO
N2	DAC	0
	JST	SAVE
	LDA	=-5
	JMP	NGO
N3	DAC	0
	JST	SAVE
	LDA	=-4
	JMP	NGO
N4	DAC	0
	JST	SAVE
	LDA	=-3
	JMP	NGO
N5	DAC	0
	JST	SAVE
	LDA	=-2
	JMP	NGO
N6	DAC	0
	JST	SAVE
	LDA	=-1
	JMP	NGO
* 
****************************************
* 
SAVE	DAC	0
	STA	ATMP
	IAB
	STA	BTMP
	JMP*	SAVE
*  
****************************************
* 
NGO	STA	PCNT
	AOA
	ALS	2	MULTIPLY BY 4
	STA	0	TO INDEX REGISTER
	LDA	=-7
	STA	CNT
* 
	CRA
	LRR	5	VORSPANNUNG
	IRS	CNT
	LLR	3
	IRS	PCNT
	JMP	*-3
* 
NXL	LLR	3
	ADD	ZERO
	JST	TP
	CRA
	IRS	CNT
	JMP	NXL
	LDA	BTMP
	IAB
	LDA	ATMP
	JMP*	N6,1	EVIL!!!
* 
*  
****************************************
* 
*  
ATMP	DAC	**	TEMPORARY STORAGE FOR A
BTMP	DAC	**	TEMPORARY STORAGE FOR B
PCNT	DAC	**
CNT	DAC	**
ZERO	DEC	48	CHARACTER ZERO
* 
********************************************************************************
* 
CR	DAC	0
	STA	ATMP
	LDA	=13
	JST	TP
	LDA	ATMP
	JMP*	CR
* 
LF	DAC	0
	STA	ATMP
	LDA	=10
	JST	TP
	LDA	ATMP
	JMP*	LF
* 
NL	DAC	0
	JST	CR
	JST	LF
	JMP*	NL
* 
SP	DAC	0
	STA	ATMP
	LDA	='040
	JST	TP
	LDA	ATMP
	JMP*	SP
* 
* 
********************************************************************************
* 
TEXT	DAC	0
	STA	ATMP
	LDA*	TEXT	GET POINTER
	STA	PTR
	IRS	TEXT	RETURN ADDRESS
* 
TLOP	LDA*	PTR
* 
	SNZ
	JMP	TDON
* 
	ICL		COPY DOWN
	SZE		DON'T PRINT ZEROES
	JST	TP
	LDA*	PTR
	CAL		CLEAR UPPER HALF
	SZE		DON'T PRINT ZEROES
	JST	TP
* 
	IRS	PTR
	JMP	TLOP	
*
TDON	LDA	ATMP
	JMP*	TEXT
* 
PTR	DAC	0
* 
********************************************************************************
* 
	END