sw/os8/v3d/sources/system/dectapes/dectape2/DF32NS.PA

   1 /1 DF32 NON SYSTEM HANDLER
   2 /
   3 /
   4 /
   5 /
   6 /
   7 /
   8 /
   9 /
  10 /
  11 /COPYRIGHT  (C)  1974,1975 BY DIGITAL EQUIPMENT CORPORATION
  12 /
  13 /
  14 /
  15 /
  16 /
  17 /
  18 /
  19 /
  20 /
  21 /
  22 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  23 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  24 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  25 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  26 /
  27 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  28 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  29 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  30 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  31 /
  32 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  33 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  34 /DIGITAL.
  35 /
  36 /
  37 /
  38 /
  39 /
  40 /
  41 /
  42 /
  43 /
  44 /
  45
  46 /       SR
  47
  48         RF08=0  /CHANGE TO 1 FOR RF08 HANDLER
  49
  50 /THE NUMBER OF PLATTERS MUST EITHER BE SET AT ASSEMBLY TIME,
  51 /OR MUST BE CHANGED VIA THE ALTER COMMAND IN BUILD
  52
  53         *0
  54
  55         -1
  56         IFNZRO RF08 <
  57         DEVICE RF;DEVICE RF;4064;RF&177;ZBLOCK 2
  58         >
  59         IFZERO RF08 <
  60         DEVICE DF;DEVICE DF;4124;DF&177;ZBLOCK 2
  61         >
  62
  63         SCA=7751
  64         SWC=7750
  65
  66         RFVERSION="A&77
  67 \f       *200
  68
  69 SYSER,  CLA CLL CML RAR /4000
  70         ISZ SYSCNT      /TRY AGAIN?
  71         SKP CLA
  72         JMP SFIELD      /WHY BOTHER
  73         CLA CLL CMA RTL
  74         TAD RF
  75         DCA RF          /RESET PARAMETERS AND TRY AGAIN
  76         JMP RETRY
  77 SCIF,   CIF 0
  78 SYSCNT, 0
  79 S6603,  6603
  80 S70,    70
  81 S7400,  7400
  82         IFZERO RF08 <S3700,     3700>
  83         IFNZRO RF08 <S377,      0377>
  84 T1,     0
  85 T2,     0
  86         ZBLOCK 224-.
  87         IFNZRO .-224 <ADRERR,QQQQ>      /ENTRY PT MUST BE RELATIVE 24
  88 DF,
  89 RF,     RFVERSION
  90         CLA CLL CMA RTL /-3
  91         DCA SYSCNT      /# TRYS ON ERROR
  92 RETRY,  TAD I RF        /HANDLER RUNS IN USER'S DATA FIELD
  93         RAL
  94         CLA RTL
  95         TAD S6603
  96         DCA SFUN        /EITHER A READ OR WRITE
  97         TAD I RF
  98         AND S70
  99         DCA SFIELD      /GET FIELD OF BUFFER
 100         TAD I RF
 101         RAL
 102         AND S7600
 103         CIA
 104         DCA T1          /SET UP WORD COUNT
 105         CLA CMA
 106         ISZ RF
 107         TAD I RF
 108         DCA T2          /BUFFER ADDRESS-1
 109         ISZ RF
 110         RDF
 111         TAD (CDF 0
 112         DCA RESRDF
 113         CDF 0
 114         TAD T1
 115         DCA I (SWC
 116         TAD T2
 117         DCA I (SCA
 118 RESRDF, HLT             /RESTORE USER'S DATA FIELD
 119         IFZERO RF08 <
 120         TAD I RF
 121         RTL
 122         AND S3700
 123         >
 124         TAD SFIELD
 125         6615            /LOAD DISK EXTENDED MEMORY
 126 S7600,  7600
 127         IFNZRO RF08 <
 128         TAD I RF
 129         RTR
 130         RTR
 131         AND S377
 132         6643            /LOAD HIGH ORDER
 133         >
 134         TAD I RF
 135         RTR
 136         RTR
 137         RAR
 138         AND S7400
 139 SFUN,   HLT             /BECOMES DISK IOT.(READ OR WRITE)
 140         RDF
 141         TAD SCIF
 142         DCA SFIELD
 143         IFZERO  RF08    <6622>
 144         IFNZRO  RF08    <6623>
 145         JMP .-1
 146         KRS
 147         AND (177
 148         TAD (-3
 149         SNA CLA
 150         KSF
 151         JMP .+3
 152         CIF CDF 0       /RETURN TO OS/8 IF USER TYPED ^C
 153         JMP I S7600
 154         ISZ RF
 155         6621            /SKIP ON ERROR
 156         IFNZRO RF08 <SKP        /SENSE OF SKIP IS REVERSED>
 157         JMP SYSER
 158         ISZ RF
 159 SFIELD, HLT             /RETURN TO PROPER FIELD
 160         6601            /CLEAR TROUBLESOME FLAG
 161         JMP I RF
 162         $
 163 \f