sw/os8/v3d/sources/system/dectapes/dectape2/RF08SY.PA

   1 /2 RF08 SYSTEM HANDLER
   2 /
   3 /
   4 /
   5 /
   6 /
   7 /
   8 /
   9 /
  10 /
  11 /COPYRIGHT  (C)  1974,1975 BY DIGITAL EQUIPMENT CORPORATION
  12 /
  13 /
  14 /
  15 /
  16 /
  17 /
  18 /
  19 /
  20 /
  21 /
  22 /THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT NOTICE
  23 /AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL EQUIPMENT
  24 /CORPORATION.  DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
  25 /FOR ANY ERRORS THAT MAY APPEAR IN THIS DOCUMENT.
  26 /
  27 /THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FURNISHED TO THE PURCHASER
  28 /UNDER A LICENSE FOR USE ON A SINGLE COMPUTER SYSTEM AND CAN BE COPIED
  29 /(WITH INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR USE IN SUCH
  30 /SYSTEM, EXCEPT AS MAY OTHERWISE BE PROVIDED IN WRITING BY DIGITAL.
  31 /
  32 /DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY FOR THE USE
  33 /OR RELIABILITY OF ITS SOFTWARE ON EQUIPMENT THAT IS NOT SUPPLIED BY
  34 /DIGITAL.
  35 /
  36 /
  37 /
  38 /
  39 /
  40 /
  41 /
  42 /
  43 /
  44 /
  45 \f/MAINTENANCE RELEASE CHANGES:
  46
  47 /1.     REMOVED SOFSET
  48 /2.     CHANGED LENGTH OF PLATTER
  49
  50         DF32=0
  51         RF08=1
  52         VERSION="B&77
  53
  54         *0
  55         -1
  56         DEVICE RF08;DEVICE SYS;4064;2007;0;1777
  57
  58         STARTB-ENDB-1
  59
  60         NOPUNC
  61         *6604
  62         ENPUNC
  63 STARTB, NOP             /FOR "SWAP"
  64 B6653,  6653
  65 B7647,  7647
  66 B7577,  7577
  67 B200,   200
  68 B7605,  7605
  69 B7751,  7751
  70         ZBLOCK  6622-.
  71         TAD I B6653
  72         CDF 10
  73         DCA I B7647
  74         CDF 0
  75         ISZ B6653
  76         ISZ B7647
  77         JMP .-6         /MOVE FIELD 1 RESIDENT UP
  78         IFNZRO  RF08    <6643>
  79         6615
  80         7600
  81         TAD B7577
  82         DCA I B7751
  83         TAD B200
  84         6603            /NOW READ IN FIELD 0 RESIDENT FROM RECORD 1/2
  85         IFNZRO  RF08    <6623>
  86         IFNZRO  DF32    <6622>
  87         JMP .-1
  88         6621
  89         IFNZRO  RF08    <SKP>
  90         HLT             /ERROR READING SYSTEM IN
  91 ENDB,   JMP I B7605
  92 \f       /BOOTSTRAP FOR DISK MONITOR IS AS FOLLOWS:
  93
  94         /       LOCATION        CONTENTS
  95         /       7750            7600
  96         /       7751            6603
  97         /       7752            6622
  98         /       7753            5352
  99         /       7754            5752
 100 \f       *200
 101
 102         NOPUNCH
 103         *7600
 104         ENPUNCH
 105
 106         ZBLOCK 7
 107 SHNDLR, VERSION
 108         CLA CLL CMA RTL /-3
 109         DCA SYSCNT      /# TRYS ON ERROR
 110         TAD I SHNDLR
 111         RAL
 112         CLA RTL
 113         TAD S6603
 114         DCA SFUN        /EITHER A READ OR WRITE
 115         TAD I SHNDLR
 116         AND S70
 117         DCA SFIELD      /GET FIELD OF BUFFER
 118         TAD I SHNDLR
 119         RAL
 120         AND S7600
 121         CIA
 122         DCA SWC         /SET UP WORD COUNT
 123         CLA CMA
 124         ISZ SHNDLR
 125         TAD I SHNDLR
 126         DCA SCA         /BUFFER ADDRESS-1
 127         ISZ SHNDLR
 128         IFNZRO  DF32 <
 129         TAD I SHNDLR
 130         RTL
 131         AND S3700>
 132         TAD SFIELD
 133         6615            /LOAD DISK EXTENDED MEMORY
 134 S7600,  7600
 135         IFNZRO RF08 <
 136         TAD I SHNDLR
 137         RTR
 138         RTR
 139         AND S377
 140         6643            /LOAD HIGH ORDER>
 141         TAD I SHNDLR
 142         RTR
 143         RTR
 144         RAR
 145         AND S7400
 146 SFUN,   HLT             /BECOMES DISK IOT.(READ OR WRITE)
 147         RDF
 148         TAD SCIF
 149         DCA SFIELD
 150         IFNZRO  DF32    <6622>
 151         IFNZRO  RF08    <6623>
 152         JMP .-1
 153         ISZ SHNDLR
 154         6621            /SKIP ON ERROR
 155         IFNZRO RF08 <SKP        /SENSE OF SKIP IS REVERSED>
 156         JMP SYSER
 157         ISZ SHNDLR
 158 SFIELD, HLT             /RETURN TO PROPER FIELD
 159         6601            /CLEAR TROUBLESOME FLAG
 160         JMP I SHNDLR
 161         ZBLOCK 2
 162 SYSER,  CLA CLL CML RAR /4000
 163         ISZ SYSCNT      /TRY AGAIN?
 164         SKP CLA
 165         JMP SFIELD      /WHY BOTHER
 166         CLA CLL CMA RTL
 167         TAD SHNDLR
 168         DCA SHNDLR      /RESET PARAMETERS AND TRY AGAIN
 169         IFNZRO RF08     <IFNZRO .-7700  <NZERR>;        SKP;    HLT>
 170         JMP SHNDLR+3
 171 SCIF,   CIF 0
 172 SYSCNT, 0
 173         IFNZRO DF32     <IFNZRO .-7700  <NZERR>;        SKP;    HLT>
 174 S6603,  6603
 175 S70,    70
 176 S7400,  7400
 177         IFNZRO  DF32 <S3700,    3700>
 178         IFNZRO RF08 <S377,      377>
 179         SCA=7751
 180         SWC=7750
 181         $
 182 \f